Magma V2.24-7, JupyterLab 0.32.1

In this file the letter $o$ stands for the parameter $\alpha$ in the paper (On degenerations of Z/2-Godeaux surfaces, by Dias-Rito-Urzúa).

Denote by $Y$ an element of Coughlan's family of surfaces, whose general surface is the universal covering of a $\mathbb Z_2$-Godeaux surface. Our computer experiments over finite fields say that there are values of the parameters for which the surface $Y\subset\mathbb P(1,2,2,2,3,3,3,3,4)$ contains a node, which is the only point that is fixed by the "Godeaux" involution. Moreover, the smooth minimal model of the quotient of $Y$ by that involution is a $D_{23}$ elliptic surface. The coordinates of that point satisfy $y_2=y_3-y_1=z_2-z_1=z_4+z_3=0$.

Here we use this information to obtain a 6-dimensional family of $D_{23}$ elliptic surfaces as quotients of a codimension 1 subset of Coughlan's family of surfaces.

We load the $20$ equations that define Coughlan's family, and we impose $y_2=0$, $y_3=y_1$, $z_2=z_1$ $z_4=-z_3$. (We fix $o=7$, but one can check that the relation we will get is independent of this choice.)

In [1]:
K:=Rationals();
R<t,z1,z3,y1,x,l1,l2,l3,l4,l5,l6>:=PolynomialRing(K,11,"grevlex");
o:=7;
y2:=0;y3:=y1;z2:=z1;z4:=-z3;
load "Eqs20";

Loading "Eqs20"

We eliminate all variables except the parameters.

In [2]:
I:=EliminationIdeal(Ideal(Eqs20),4);























This gives one single relation, that factors as:













In [3]:



    


Factorization(Basis(I)[1]);


























[
    <l1 + l3, 1>,
    <l1 + l2 - l3 + 48*l4 + 384, 2>,
    <x, 7>,
    <l1^2*l4^2 - 2*l1*l3*l4^2 + l3^2*l4^2 - 72*l2*l4^3 - 1/4*l1^3 + 3/4*l1^2*l3 
        - 3/4*l1*l3^2 + 1/4*l3^3 + 14*l1*l2*l4 - 14*l2*l3*l4 - 8*l2^2, 1>
]























Let's concentrate on the relation $l_1+l_3=0$.


We pick an arbitrary surface on this family and show that its quotient by the "Godeaux" involution is indeed a $D_{23}$ elliptic surface with a $(-4)$-curve.


To speed up computations, we work over a finite field.













In [4]:



    


K:=FiniteField(37);
R<x,y1,y2,y3,z1,z2,z3,z4,t>:=PolynomialRing(K,[1,2,2,2,3,3,3,3,4]);
P:=ProjectiveSpace(R);
o:=3;l1:=2;l2:=5;l3:=-2;l4:=7;l5:=6;l6:=8;
load "Eqs20";
Y:=Scheme(P,Eqs20);


























Loading "Eqs20"























The subscheme of $Y$ that satisfy $y_2=y_3-y_1=z_2-z_1=z_4+z_3=0$ is a point, which is singular:













In [5]:



    


pt:=PrimeComponents(Scheme(Y,[y2,y1-y3,z1-z2,z3+z4]))[1];
Dimension(pt);
Degree(pt);
p:=P![1,-13,0,-13,104,104,-320,320,0];
p in pt;
IsSingular(Y,p);


























0
1
true (1 : 24 : 0 : 24 : 30 : 30 : 13 : 24 : 0)
true























Now we compute the linear system of the curves of degree 5 that contain this point and are preserved by the "Godeaux" involution.













In [6]:



    


s:=Sections(LinearSystem(P,5));
for i in [1..#s] do s[i]:=s[i]+Evaluate(s[i],[-x,y3,-y2,y1,-z2,-z1,z4,z3,-t]);end for;
ss:=[];for q in s do if q ne 0 then Append(~ss,q);end if;end for;s:=ss;
L:=LinearSystem(P,s);
L:=LinearSystemTrace(L,Y);
pt eq (Y meet BaseScheme(L));


























true























This system defines a map $\phi$ to $\mathbb P^{10}:$













In [7]:



    


s:=Sections(L);
#s eq 11;
P10<a1,a2,a3,a4,a5,a6,a7,a8,a9,a10,a11>:=ProjectiveSpace(K,10);
phi:=map<P->P10|s>;


























true























This map resolves the singularity of $Y$, and is of degree 2 onto a surface. We verify that this surface is a $D_{23}$ elliptic surface, with a $(-4)$-curve that is the image of the node of $Y$.


The direct computation of $\phi(Y)$ seems unattainable, so we compute the image of several points and then the linear systems $L_2,$ $L_3$ of surfaces of degree 2, 3 through these points.













In [8]:



    


L3:=LinearSystem(P,3);
PTS:=[];
while #PTS lt 20 do 
  PTS:=PTS cat [phi(Scheme(Y,[Random(L3),Random(L3)]))];
end while;

L2:=LinearSystem(P10,2);
L3:=LinearSystem(P10,3);
for q in PTS do
  L2:=LinearSystem(L2,q);
  L3:=LinearSystem(L3,q);
end for;
















































These quadrics and cubics define an irreducible surface:













In [9]:



    


s:=MinimalBasis(Sections(L2) cat Sections(L3));
G:=Surface(P10,s);
















































In order to show that $G$ is smooth, and to avoid the computation of all $8\times 8$ minors of matrices of partial derivatives, we random such minors until they define an empty subscheme of $G$:













In [10]:



    


per8:=Permutations({1..11},8);

dim:=2;det:=[];
repeat
  s8:={};
  repeat
    s8:=s8 join {Random(s)};
  until #s8 eq 8;
  M:=Matrix([[Derivative(q,j):j in Random(per8)]:q in s8]);
  Append(~det,Determinant(M));
  dim:=Dimension(Scheme(G,det));
until dim eq -1;
dim;


























-1























The canonical divisor of $G$:













In [11]:



    


KD:=CanonicalDivisor(G);
SelfIntersection(KD);


























0























The system $2K_Y$ is given by the pullback of $2K_G+C,$ where $C$ is the $(-4)$-curve corresponding to the node of $Y$.
This means that there exists an invariant bicanonical curve through the node of $Y$.
Its quotient in $G$ is $H:=F_3+C$, where $3F_3$ is an elliptic fibre:













In [12]:



    


l:=LinearSystem(LinearSystem(P,[x^2,y1+y3]),pt);
H:=G meet phi(Scheme(P,Sections(l)));
pc:=PrimeComponents(H);
pc:=[Curve(P10,DefiningEquations(q)):q in pc];
[IsAbsolutelyIrreducible(q):q in pc];
[ArithmeticGenus(q):q in pc];
F3:=Divisor(G,pc[1]);C:=Divisor(G,pc[2]);
SelfIntersection(F3);SelfIntersection(C);
RiemannRochSpace(F3);
RiemannRochSpace(3*F3);


























[ true, true ]
[ 1, 0 ]
0
-4
Full Vector space of degree 1 over GF(37)
Mapping from: Full Vector space of degree 1 over GF(37) to Function Field of P10
given by a rule
Full Vector space of degree 2 over GF(37)
Mapping from: Full Vector space of degree 2 over GF(37) to Function Field of P10
given by a rule























Now we compute the double elliptic fibre $2F_2:$













In [13]:



    


t,F2:=IsLinearSystemNonEmpty(F3+KD);
















































And do some checkings:













In [14]:



    


SelfIntersection(F2);
RiemannRochSpace(2*F2);
C2:=Curve(P10,Basis(Ideal(F2)));
IsAbsolutelyIrreducible(C2);
Genus(C2);


























0
Full Vector space of degree 2 over GF(37)
Mapping from: Full Vector space of degree 2 over GF(37) to Function Field of P10
given by a rule
true
1























The invariants of $G$:













In [15]:



    


GeometricGenus(G);
Irregularity(G);


























0
0























Finally we check that $CF_3=4$ and $C$ is the image of the node of $Y$.













In [16]:



    


IntersectionNumber(C,F3);
pb:=Y meet Pullback(phi,pc[2]);
[pt] eq PrimeComponents(pb);


























4
true